#vars $abc: a b c d e f g h i j k l m n o p q r s t u v w x y z.
#vars $vowel: a e i o u.

SANDHI:
        <$abc> == $abc <>
        <> ==
        <$vowel#1 $vowel#2> == $vowel#2 <>.

VERB:
        {slot_iv} == <slot_iii> <slot_ii>
        {slot_iv negative 1 sg} == s i
        {slot_iii negative} == h a
        {slot_iii} ==
        {slot_ii 1 sg} == n i
        {slot_ii 2 sg} == u
        {slot_ii 3 sg} == a
        {slot_ii 1 pl} == t u
        {slot_ii 2 pl} == m
        {slot_ii 3 pl} == w a
        {slot_i past} == l i
        {slot_i negative past} == k u
        {slot_i future} == t a
        {} == SANDHI:<<slot_iv> <slot_i> "<root>">.

WANT:
        {} == VERB
        {root} == t a k a.

#hide SANDHI VERB. 
#show
      <positive future 1 sg>
      <positive future 2 sg>
      <positive future 3 sg>
      <positive future 1 pl>
      <positive future 2 pl>
      <positive future 3 pl>
      <negative future 1 sg>
      <negative future 2 sg>
      <negative future 3 sg>
      <negative future 1 pl>
      <negative future 2 pl>
      <negative future 3 pl>
      <positive past 1 sg>
      <positive past 2 sg>
      <positive past 3 sg>
      <positive past 1 pl>
      <positive past 2 pl>
      <positive past 3 pl>
      <negative past 1 sg>
      <negative past 2 sg>
      <negative past 3 sg>
      <negative past 1 pl>
      <negative past 2 pl>
      <negative past 3 pl>.