% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
% File:          gdp.dtr                                                    %
% Purpose:       This program models a fragment of Pali nominal             %
%                declension, and is meant to facilitate comparisons         %
%                among Old and Middle Indic declensional systems.           %
% Author:        Greg Stump, 06/10/99                                       %
% Email:         gstump@pop.uky.edu                                         %
% Address:       Dept. of English, Univ. of Kentucky, Lexington, KY 40506   %
% Documentation: eventually                                                 %
% Related files: gdv.dtr, gde.dtr                                           %
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% Transliteration follows the ITRANS encoding scheme.

#atom M N ~n Ch ~N T Th D Dh Sh L.
#vars $abc: a b bh ch Ch d dh D Dh e g gh h i j jh k kh l L m M n N ~n ~N o p ph r s sh Sh t th T Th u v y ;.
#vars $consonant: b bh ch Ch d dh D Dh g gh h j jh k kh l L m n N ~n ~N p ph r s sh Sh t th T Th v y.
#vars $vowel2: a e i o u.
#vars $vowel: a e i o u.
#vars $noniuvowel: a e o.
#vars $iuvowel: i u.
#vars $number: singular plural.
#vars $part: stem vstem longvstem suff.
#vars $gender: masculine feminine neuter.
#vars $nonneut: masculine feminine.
#vars $nonfem: masculine neuter.
#vars $genloc: gen loc.
#vars $direct: nom acc.
#vars $oblique: ins dat abl gen loc.

SANDHI:
    <> ==
    <endofword> ==
    <$consonant s endofword> == $consonant
    <$abc> == $abc <>
    <a s bh> == o <bh>
    <t bh> == d <bh>
    <$vowel ;> == <$vowel $vowel>
    <$vowel $vowel $vowel> == <$vowel $vowel>
    <$vowel $vowel M> == <$vowel M>
    <M t> == n <t>
    <a e> == <a i>
    <$iuvowel $noniuvowel> == $iuvowel y <$noniuvowel>
    <a y $consonant> == <e $consonant>
    <a v $consonant> == <o $consonant>
    <i y $consonant> == <i i $consonant>
    <u v $consonant> == <u u $consonant>.

NOMINALS:
    <$num $direct> == <$num dir $direct>
    <$num $oblique> == <$num obl $oblique>
    <vstem> == "<lex root>" "<lex stemvowel>"
    <extendedroot> == "<lex root>"
    <extendedvstem> == "<extendedroot>" "<lex stemvowel>"
    <nstem> == "<vstem>" n 
    <rstem> == "<vstem>" r
    <smstem> == "<vstem>" s m
    <longvstem> == "<vstem>" ; 
    <longnstem> == <longvstem> n
    <longrstem> == <longvstem> r
    <stem> == "<vstem>"
    <suff> == 
    <> == SANDHI:<"<"<gender>" stem>" "<"<gender>" suff>" endofword>
    <masculine> == "<>"
    <neuter> == "<>"
    <feminine> == "<>"
    <suff singular dir acc> == M
    <suff singular obl ins> == a a
    <suff singular obl gen> == o
    <suff singular obl loc> == i
    <suff plural obl ins> == h i
    <suff plural obl gen> == a M
    <suff plural obl loc> == s u
    <suff plural dir> == o
    <$number dat> == "<$number gen>"
    <$gender $part singular obl abl> == "<$gender $part singular obl ins>"
    <neuter $part $number dir nom> == "<neuter $part $number dir acc>"
    <plural abl> == "<plural ins>"
    <$gender stem plural obl gen> == "<longnstem plural obl gen>".

VOWEL_STEM_NOMINALS:
    <> == NOMINALS
    <stem singular obl loc> == <smstem>
    <$nonfem stem singular obl abl> == <smstem>
    <neuter suff plural dir acc> == n i
    <neuter stem plural dir acc> == "<extendedroot>" "<lex stemvowel>" ;
    <suff singular obl gen> == s s a
    <suff singular obl loc> == i M
    <$nonfem suff singular obl abl> == a a.

I_OR_U_STEM_NOMINALS: 
    <> == VOWEL_STEM_NOMINALS
    <gender> == masculine
    <strongstem> == "<lex root>" a <stemconsonant "<lex stemvowel>">
    <stemconsonant i> == y
    <stemconsonant u> == v
    <stem singular obl ins> == <nstem>
    <masculine stem plural dir> == <strongstem>
    <stem plural obl> == "<longvstem plural obl>"
    <suff singular obl ins> == NOMINALS.

FEMININE_STEM_NOMINALS:
    <> == VOWEL_STEM_NOMINALS
    <gender> == feminine
    <stem> == "<vstem>"
    <stem plural obl> == <longvstem>
    <stem singular obl> == <stem>
    <suff singular obl> == a a.

LONG_A_STEM_NOMINALS:
    <> == FEMININE_STEM_NOMINALS
    <lex stemvowel> == a
    <stem> == <longvstem>
    <suff singular obl> == y a
    <suff plural dir> ==.

NONALTERNATING_CONSONANT_STEM_NOMINALS:
    <> == NOMINALS
    <suff singular dir acc> == a NOMINALS. 

Devii:
    <> == FEMININE_STEM_NOMINALS
    <lex meaning> == goddess
    <lex root> == d e v
    <lex stemvowel> == i
    <singular nom> == SANDHI:<"<longvstem>">.

Sirii:
    <> == FEMININE_STEM_NOMINALS
    <lex meaning> == glory 
    <lex root> == s i r 
    <lex stemvowel> == i
    <singular nom> == SANDHI:<"<longvstem>">.

Nadii:
    <> == FEMININE_STEM_NOMINALS
    <lex meaning> == river
    <lex root> == n a d
    <lex stemvowel> == i
    <singular nom> == SANDHI:<"<longvstem>">.

Suuchi:
    <lex meaning> == bright
    <lex root> == s u u ch
    <lex stemvowel> == i.

Suuchi_F:
    <> == FEMININE_STEM_NOMINALS
    <lex> == Suuchi.

Suuchi_M:
    <> == I_OR_U_STEM_NOMINALS
    <lex> == Suuchi.

Vaachaa:
    <> == LONG_A_STEM_NOMINALS
    <lex meaning> == speech
    <lex root> == v a a ch.

#hide 
SANDHI 
NOMINALS 
VOWEL_STEM_NOMINALS 
I_OR_U_STEM_NOMINALS 
FEMININE_STEM_NOMINALS 
LONG_A_STEM_NOMINALS 
NONALTERNATING_CONSONANT_STEM_NOMINALS 
Suuchi.

#show <lex meaning>
    <gender>
    <singular nom>
    <singular acc> 
    <singular ins> 
    <singular dat> 
    <singular abl>
    <singular gen>
    <singular loc>
    <plural nom>
    <plural acc>
    <plural ins>
    <plural dat>
    <plural abl>
    <plural gen>
    <plural loc>.
 
% The next line is the Revision Control System Id: do not delete it.
% $Id$