% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
% File:          gde.dtr                                                      %
% Purpose:       This program models a fragment of Epic Sanskrit nominal      %
%                declension, and is meant to facilitate comparisons           %
%                among Old and Middle Indic declensional systems.             %
% Author:        Greg Stump, 06/10/99                                         %
% Email:         gstump@pop.uky.edu                                           %
% Address:       Dept. of English, Univ. of Kentucky, Lexington, KY 40506     %
% Documentation: eventually                                                   %
% Related files: gdv.dtr, gdp.dtr                                             %
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% Transliteration follows the ITRANS encoding scheme.

#atom Ri R^i RI R^I Li LI M H ~N Ch ~n T Th D Dh N Sh ,h.
#vars $abc: Ri RI Li LI M H ~N Ch ~n T Th D Dh N Sh a b bh c ch d dh e g gh h i j jh k kh l m n o p ph r s sh t th u v y ; ,h.
#vars $obstruent: ,h b bh c ch d dh g gh h j jh k kh l p ph s sh t th Ch T Th D Dh Sh.
#vars $consonant: ,h b bh c ch d dh g gh h j jh k kh l m n p ph r s
sh t th v y ~N Ch ~n T Th D Dh N Sh.
#vars $consonant2: ,h b bh c ch d dh g gh h j jh k kh l m n p ph r
s sh t th v y ~N Ch ~n T Th D Dh N Sh.
#vars $pal: ch Ch j jh sh ~n y.
#vars $nonpal: b bh d dh D Dh g gh h k kh l m n ~N N p ph r s Sh t th T Th v. 
#vars $coronalconsonant: ch Ch j jh ~n T Th D Dh N t th d dh n sh s.
#vars $retroflexcontinuant: r Ri RI Sh.
#vars $vowel2: a e i o u Ri.
#vars $nonivowel: a e o u Ri.
#vars $nonuvowel: a e i o Ri.
#vars $ruki: r Ri o u k e i.
#vars $vowel: a e i o u Ri.
#vars $vowelplus: a e i o u Ri n m y v.
#vars $offon: retron retroff.
#vars $nonneut: masculine feminine.
#vars $part: stem suff.
#vars $gender: masculine feminine neuter.
#vars $number: singular dual plural.
#vars $direct: nom acc.
#vars $oblique: ins dat abl gen loc.

SANDHI:
    <$offon> ==
    <$offon $vowel ,h> == $vowel
    <$offon $consonant $consonant2 $obstruent ,h> == <$offon $consonant ,h>
    <$offon $consonant $obstruent ,h> == <$offon $consonant ,h>
    <$offon $nonpal ,h> == $nonpal <$offon ,h>
    <$offon $pal ,h> == k <$offon ,h>
    <$offon $consonant n $consonant2> == <$offon $consonant a $consonant2> 
    <$offon $pal s> == <$offon k s>
    <$offon $abc> == $abc <$offon>
    <$offon a s bh> == o <$offon bh>
    <$offon $pal bh> == g <$offon bh>
    <$offon j n> == <retroff j ~n>
    <$offon t bh> == d <retroff bh>
    <$offon $ruki s $vowel> == <$offon $ruki Sh $vowel>
    <$offon $vowel ;> == <$offon $vowel $vowel>
    <$offon r ;> == <$offon RI>
    <$offon Ri Ri> == <$offon RI>
    <$offon Ri> == R^i <$offon>
    <$offon RI> == R^I <$offon>
    <$offon $consonant r $consonant2> == <$offon $consonant Ri $consonant2>
    <$offon $vowel $vowel $vowel2> == <$offon $vowel $vowel2>
    <$offon $consonant a i i> == <$offon $consonant a i>
    <$offon $consonant a i> == <$offon $consonant e>
    <$offon M t> == n <retroff t>
    <$offon a e> == <$offon a i>
    <retroff $retroflexcontinuant> == <retron $retroflexcontinuant>
    <$offon i $nonivowel> == y <$offon $nonivowel>
    <$offon i i $nonivowel> == <$offon i $nonivowel>
    <$offon u $nonuvowel> == v <$offon $nonuvowel>
    <$offon u u $nonuvowel> == <$offon u $nonuvowel>
    <$offon a y $consonant> == <$offon e $consonant>
    <$offon a v $consonant> == <$offon o $consonant>
    <$offon i y $consonant> == <$offon i i $consonant>
    <$offon u v $consonant> == <$offon u u $consonant>
    <retron n $vowelplus> == <retroff N $vowelplus>
    <retron $coronalconsonant> == <retroff $coronalconsonant>.

NOMINALS:
    <$number $direct> == <$number dir $direct>
    <$number $oblique> == <$number obl $oblique>
    <vstem> == "<lex root>" "<lex stemvowel>"
    <nstem> == "<vstem>" n 
    <strongstem> == <gunastem>
    <smstem> == "<vstem>" s m
    <longvstem> == "<vstem>" ; 
    <longnstem> == "<longvstem>" n
    <stem> == "<vstem>"
    <suff> == 
    <> == SANDHI:<retroff "<"<gender>" stem>" "<"<gender>" suff>" ,h> 
    <masculine> == "<>"
    <neuter> == "<>"
    <feminine> == "<>"
    <suff singular dir nom> == s
    <suff singular dir acc> == m
    <suff singular obl dat> == e
    <suff singular obl ins> == a a
    <suff singular obl gen> == a s
    <suff singular obl loc> == i
    <suff dual dir> == a u
    <suff dual obl> == bh y a a m
    <suff dual obl gen> == o s
    <dual obl loc> == <dual obl gen>
    <suff plural obl dat> == bh y a s
    <suff plural obl ins> == bh i s
    <suff plural obl gen> == a a m
    <suff plural obl loc> == s u
    <$gender $part singular obl abl> == "<$gender $part singular obl gen>"
    <suff plural dir> == a s
    <plural obl abl> == "<plural obl dat>"
    <stemres> ==
    <epenres> ==
    <stemobs> ==
    <gunastem> == "<lex root>" a "<stemres>" "<stemobs>"
    <vrddhistem> == <longvstem> "<stemres>" "<stemobs>"
    <neuter suff singular dir> ==
    <neuter suff dual dir> == i i
    <neuter suff plural dir> == i.

VOWEL_STEM_NOMINALS:
    <> == NOMINALS
    <feminine suff plural dir acc> == s
    <stem plural obl gen> == "<longnstem plural obl gen>"
    <suff plural dir acc> == n
    <stem plural dir acc> == "<longvstem plural dir acc>"
    <neuter stem plural dir> == <longnstem>
    <feminine suff singular obl loc> == a m.

I_OR_U_STEM_NOMINALS: 
    <> == VOWEL_STEM_NOMINALS
    <gender> == masculine
    <stem dual dir> == <longvstem>
    <suff dual dir> ==
    <stemres> == <stemconsonant "<lex stemvowel>">
    <stemconsonant i> == y
    <stemconsonant u> == v
    <neuter stem dual dir> == <nstem>
    <neuter stem dual obl gen> == <nstem>
    <masculine stem singular obl ins> == <nstem>
    <feminine stem singular obl ins> == <vstem>
    <stem plural dir nom> == "<strongstem>"
    <stem singular obl> == "<strongstem>"
    <stem singular obl loc> == "<lex root>"
    <$nonneut suff singular obl gen> == s
    <$nonneut suff singular obl loc> == a u
    <neuter stem singular obl> == <nstem>.

FEMININE_I_OR_U_STEM_NOMINALS:
    <> == I_OR_U_STEM_NOMINALS
    <gender> == feminine
    <stem singular obl> == LONG_VOWEL_STEM_NOMINALS
    <feminine suff singular obl> == LONG_VOWEL_STEM_NOMINALS.

LONG_VOWEL_STEM_NOMINALS:
    <> == VOWEL_STEM_NOMINALS
    <lex stemvowel> == u
    <vstem> == "<lex root>" "<lex stemvowel>" ;
    <gender> == feminine
    <stem singular obl> == "<vstem>" "<epenres>" a
    <longvstem> == "<vstem>".

LONG_VOWEL_STEM_NOMINALS_2:
    <> == LONG_VOWEL_STEM_NOMINALS
    <suff singular dir nom> ==.

RADICAL_LONG_VOWEL_STEM_NOMINALS:
    <> == LONG_VOWEL_STEM_NOMINALS
    <vstem $number dir acc> == NONALTERNATING_CONSONANT_STEM_NOMINALS
    <lex stemvowel> == NONALTERNATING_CONSONANT_STEM_NOMINALS
    <vstem> == "<lex root>".

NONALTERNATING_CONSONANT_STEM_NOMINALS:
    <> == NOMINALS
    <lex stemvowel> == a
    <stem> == "<vstem>" "<stemobs>"
    <suff singular dir acc> == a NOMINALS
    <neuter stem plural dir> == "<longvstem>" M "<stemobs>".

Devii:
    <> == LONG_VOWEL_STEM_NOMINALS_2
    <lex meaning> == goddess
    <lex root> == d e v
    <lex stemvowel> == i.

Shrii:
    <> == RADICAL_LONG_VOWEL_STEM_NOMINALS
    <lex meaning> == glory
    <lex root> == sh r i y.

Nadii:
    <> == LONG_VOWEL_STEM_NOMINALS_2
    <lex meaning> == river
    <lex root> == n a d
    <lex stemvowel> == i.

Shuuchi:
    <lex meaning> == bright
    <lex root> == sh u u ch
    <lex stemvowel> == i.

Shuuchi_F:
    <> == FEMININE_I_OR_U_STEM_NOMINALS
    <lex> == Shuuchi.

Shuuchi_M:
    <> == I_OR_U_STEM_NOMINALS
    <lex> == Shuuchi.

Vaach:
    <> == NONALTERNATING_CONSONANT_STEM_NOMINALS
    <lex meaning> == speech
    <lex root> == v a a ch
    <lex stemvowel> ==
    <gender> == feminine.

#hide 
SANDHI 
NOMINALS 
VOWEL_STEM_NOMINALS 
I_OR_U_STEM_NOMINALS 
FEMININE_I_OR_U_STEM_NOMINALS 
LONG_VOWEL_STEM_NOMINALS 
LONG_VOWEL_STEM_NOMINALS_2 
RADICAL_LONG_VOWEL_STEM_NOMINALS 
NONALTERNATING_CONSONANT_STEM_NOMINALS 
Shuuchi.

#show <lex meaning>
      <gender>
      <singular nom>
      <singular acc> 
      <singular ins> 
      <singular dat> 
      <singular abl>
      <singular gen>
      <singular loc>
      <dual nom>
      <dual acc> 
      <dual ins> 
      <dual dat> 
      <dual abl>
      <dual gen>
      <dual loc>
      <plural nom>
      <plural acc>
      <plural ins>
      <plural dat>
      <plural abl>
      <plural gen> 
      <plural loc>.