% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
%                                                                           %
% File:      sktcorad.dtr                                                   %
% Purpose:   This program models a fragment of Sanskrit nominal             %
%            declension.                                                    %
% Author:    Greg Stump, May 2000                                           %
% Address:   Dept. of English, Univ. of Kentucky, Lexington, KY 40506       %
% e-mail:    gstump@pop.uky.edu                                             %
%                                                                           %
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% Transliteration follows the ITRANS encoding scheme.

#atom endofword Ri R^i RI R^I Li LI M H ~N Ch ~n T Th D Dh N Sh.
#vars $abc: Ri RI Li LI M H ~N Ch ~n T Th D Dh N Sh a b bh ch d dh e g gh h i j jh k kh l m n o p ph r s sh t th u v y ;.
#vars $obstruent: endofword b bh ch d dh g gh h j jh k kh l p ph s sh t th Ch T Th D Dh Sh.
#vars $consonant: endofword b bh ch d dh g gh h j jh k kh l m n p ph r s sh t th v y ~N Ch ~n T Th D Dh N Sh.
#vars $coronalconsonant: ch Ch j jh ~n T Th D Dh N t th d dh n sh s.
#vars $retroflexcontinuant: r Ri RI Sh.
#vars $ruki: r Ri o u k e i.
#vars $vowel: a e i o u Ri.
#vars $vowelplus: a e i o u Ri n m y v.
#vars $part: stem suff.
#vars $gender: masculine feminine neuter.
#vars $number: sg pl.
#vars $case: nom voc acc ins dat abl gen loc.
#vars $direct: nom voc acc.
#vars $oblique: ins dat abl gen loc.
#vars $noncoronal: $abc - $coronalconsonant.

SANDHI:
    <endofword> == 
    <$abc> == $abc <>
    <$ruki s $vowel> == <$ruki Sh $vowel>
    <d s> == t <s>
    <t bh> == d <bh>
    <Ri> == R^i <>
    <Ri Ri> == R^I <>
    <M t> == <n t>
    <a i> == <e>
    <a e> == a i <>
    <$consonant s endofword> == <$consonant endofword>
    <$vowel ;> == <$vowel $vowel>
    <$vowel#1 $vowel#1 ;> == <$vowel#1 $vowel#1>
    <$vowel#1 $vowel#1 $vowel#2> == <$vowel#1 $vowel#2>
.

NOMINAL:
    {} == SANDHI:<"<stem>" "<suff>" endofword> 
    {vstem} == "<root>" "<stemvowel>"
    {longvstem} == "<vstem>" ; 
    {longnstem} == "<longvstem>" n
    {stem} == "<vstem>"
    {cat} == noun
    {suff sg nom} == s
    {suff neuter sg acc} ==
    {suff sg acc} == m
    {suff sg dat} == e
    {suff sg ins} == a a
    {suff sg gen} == a s
    {suff sg loc} == i
    {suff pl !neuter $direct} == a s
    {suff pl dat} == bh y a s
    {suff pl ins} == bh i s
    {suff pl gen} == a a m
    {suff pl loc} == s u
    {$part sg abl/gen} =+= "<>"
    {pl abl/dat} =+= "<>"
    {stemobs} ==
    {suff neuter pl acc} == i
    {$part neuter nom/acc} =+= "<>"
    {$part voc/nom} =+= "<>"
    {!coradical feminine} =+= "<coradical>"
.

VOWEL_STEM:
    {} == NOMINAL
    {suff feminine pl acc} == ; s
    {suff pl gen} == ; n NOMINAL
    {suff masculine pl acc} == ; n
    {stem neuter pl $direct} == <longnstem>
    {suff feminine sg loc} == a m
.

SHORT_A_STEM: 
    {} == VOWEL_STEM
    {stemvowel} == a
    {estem} == "<root>" e
    {stem sg ins} == <estem>
    {stem masculine pl nom} == <vstem>
    {stem pl dat} == <estem>
    {stem pl loc} == <estem>
    {suff sg voc} ==
    {suff sg ins} == n a
    {suff sg dat} == a y a
    {suff sg abl} == a t
    {suff sg gen} == s y a
    {suff pl ins} == e s
    {suff neuter/masculine sg acc} =+= "<>"
.

LONG_VOWEL_STEM:
    {} == VOWEL_STEM
    {stem} == "<root>" "<stemvowel>" ;
    {gender} == feminine
    {stem feminine sg $oblique} == <stem> "<stemres>" a
.

LONG_VOWEL_STEM2:
    {} == LONG_VOWEL_STEM
    {suff feminine sg nom} ==
.

LONG_A_STEM:
    {} == LONG_VOWEL_STEM2
    {stemres} == y
    {stemvowel} == 
    {stem sg ins} == "<root>" <stemres>
    {stem sg voc} == "<root>"
    {suff sg voc} == i
.

CONSONANT_STEM:
    {} == NOMINAL
    {stemvowel} == 
    {stem} == "<vstem>" "<stemobs>"
    {stem neuter pl $direct} == "<longvstem>" M "<stemobs>"
    {suff !neuter acc sg} == a NOMINAL
.

Ashva:
    {meaning} == horse
    {} == SHORT_A_STEM
    {gender} == masculine
    {root} == a sh v
.

Daana:
    {meaning} == gift
    {} == SHORT_A_STEM
    {gender} == neuter
    {root} == d a a n
.

Paapa:
    {meaning} == evil
    {} == SHORT_A_STEM
    {cat} == adjective
    {root} == p a a p
    {coradical} == "Paapaa"
.

Paapaa:
    {} == LONG_A_STEM
    {root} == p a a p a
.

Senaa:
    {meaning} == army
    {} == LONG_A_STEM
    {root} == s e n a
.

Hrd:
    {} == CONSONANT_STEM
    {meaning} == heart
    {gender} == neuter
    {root} == h Ri d 
    {coradical} == "Hrdaya"
    {!coradical $direct} =+= <coradical>
.

Hrdaya:
    {} == SHORT_A_STEM
    {root} == h Ri d a y
.

Trivrt:
    {} == CONSONANT_STEM
    {meaning} == threefold
    {cat} == adjective
    {root} == t r i v 
    {stemvowel} == Ri
    {stemobs} == t
    {longvstem} == <vstem>
.

Aasya:
    {} == SHORT_A_STEM
    {meaning} == mouth
    {gender} == neuter
    {root} == a a s y
.

#hide SANDHI NOMINAL CONSONANT_STEM VOWEL_STEM SHORT_A_STEM LONG_VOWEL_STEM LONG_VOWEL_STEM2 LONG_A_STEM Paapaa Hrdaya
.

#show <meaning>
      <cat>
#if <cat> = noun #then
#if <gender> = neuter #then 
      <gender>
      <neuter sg nom>
      <neuter sg voc>
      <neuter sg acc>
      <neuter sg ins> 
      <neuter sg dat> 
      <neuter sg abl>
      <neuter sg gen>
      <neuter sg loc>
      <neuter pl nom>
      <neuter pl voc>
      <neuter pl acc>
      <neuter pl ins>
      <neuter pl dat>
      <neuter pl abl>
      <neuter pl gen> 
      <neuter pl loc>
#endif
#if <gender> = masculine #then 
      <gender>
      <masculine sg nom>
      <masculine sg voc>
      <masculine sg acc>
      <masculine sg ins> 
      <masculine sg dat> 
      <masculine sg abl>
      <masculine sg gen>
      <masculine sg loc>
      <masculine pl nom>
      <masculine pl voc>
      <masculine pl acc>
      <masculine pl ins>
      <masculine pl dat>
      <masculine pl abl>
      <masculine pl gen> 
      <masculine pl loc>
#endif
#if <gender> = feminine #then 
      <gender>
      <feminine sg nom>
      <feminine sg voc>
      <feminine sg acc>
      <feminine sg ins> 
      <feminine sg dat> 
      <feminine sg abl>
      <feminine sg gen>
      <feminine sg loc>
      <feminine pl nom>
      <feminine pl voc>
      <feminine pl acc>
      <feminine pl ins>
      <feminine pl dat>
      <feminine pl abl>
      <feminine pl gen> 
      <feminine pl loc>
#endif
#elsif <cat> = adjective #then 
      <neuter sg nom>
      <neuter sg voc>
      <neuter sg acc>
      <neuter sg ins> 
      <neuter sg dat> 
      <neuter sg abl>
      <neuter sg gen>
      <neuter sg loc>
      <neuter pl nom>
      <neuter pl voc>
      <neuter pl acc>
      <neuter pl ins>
      <neuter pl dat>
      <neuter pl abl>
      <neuter pl gen> 
      <neuter pl loc>
      <masculine sg nom>
      <masculine sg voc>
      <masculine sg acc>
      <masculine sg ins> 
      <masculine sg dat> 
      <masculine sg abl>
      <masculine sg gen>
      <masculine sg loc>
      <masculine pl nom>
      <masculine pl voc>
      <masculine pl acc>
      <masculine pl ins>
      <masculine pl dat>
      <masculine pl abl>
      <masculine pl gen> 
      <masculine pl loc>
      <feminine sg nom>
      <feminine sg voc>
      <feminine sg acc>
      <feminine sg ins> 
      <feminine sg dat> 
      <feminine sg abl>
      <feminine sg gen>
      <feminine sg loc>
      <feminine pl nom>
      <feminine pl voc>
      <feminine pl acc>
      <feminine pl ins>
      <feminine pl dat>
      <feminine pl abl>
      <feminine pl gen> 
      <feminine pl loc>
#endif.



% The next line is the Revision Control System Id: do not delete it.
% $Id$